Sound Sensitive LED Project (X02)

Sound Sensitive LED Build

About

This project uses the Microphone to detect sounds. Based on the sound levels, it maps the loudness to the LED Matrix's brightness. Visually see the loudness of the surrounding sound on the LED Matrix!

Color of the LED Matrix can be adjust between 7 colors with the touch button.

This project was designed for the second generation mCookie Maker kits (102 Basic, 202 Advanced and 302 Expert kits).

Required Materials

• 1 x mCookie Core
• 1 x mCookie USB TTL (102 Kit) or 1 x mBattery (202/302 Kit)
• 1 x mCookie Sensor Hub
• 1 x mCooke LED Matrix
• 1 x Microphone Sensor
• 1 x Touch Button
• 2 x Sensor Cable
• 1 x MicroUSB Cable

Build

NOTE: When connecting sensor wires, push on the plastic connector and not on the wires. Pushing on the wire can damage them.

1. Connect the Microphone Sensor to the Sensor Hub on Pin A2/A3
2. Connect the Touch Button to the Sensor Hub on Pin 6/7
3. Grab the mCookie USBTTL or mBattery and Stack the mCookie Core on top.
4. Stack the mCookie LED Matrix on top of that.
5. Stack the mCookie Sensor on top of that.
6. Plug in the MicroUSB cable to the mCookie USBTTL or mBattery to a computer.

Program

1. Connect mCookie Core to the PC with the USB Cable. Open the Microduino IDE.

2. Copy and paste the code below and upload.

#include <Adafruit_NeoPixel.h>//Import the library for the ColorLED.
#include <stdint.h>

#define DEBUG 0

#define LEDMATRIX_PIN A0
#define MIC_PIN A2
#define TOUCH_PIN 6

#define NUMPIXELS 6

//This determines the noise loudness values to ignore and sets anything under it to 0
#define AMBIENT_THRESHOLD 40

//This sets the max noise loudness values
#define MAX_THRESHOLD 800

unsigned long debounce_time_milliseconds = 200;
unsigned long debounce_time_touch_pin = 0;

Adafruit_NeoPixel matrix = Adafruit_NeoPixel(NUMPIXELS, LEDMATRIX_PIN, NEO_GRB + NEO_KHZ800);

uint8_t current_selection = 0;
uint8_t current_selection_count = 7;

uint8_t color_matrix[9][3]  ={
  {1, 0, 0},
  {0, 1, 0},
  {0, 0, 1},
  {0, 1, 1},
  {1, 0, 1},
  {1, 1, 0},
  {1, 1, 1}
};


void setup() {
  Serial.begin(9600);
  // put your setup code here, to run once:
  pinMode(MIC_PIN, INPUT);
  pinMode(TOUCH_PIN, INPUT);

  matrix.begin();
  matrix.show();
}

void loop() {
  // put your main code here, to run repeatedly:

  //Check if touch button is pressed.
  if( !digitalRead(TOUCH_PIN ) 
      && 
      ((millis() - debounce_time_touch_pin ) > debounce_time_milliseconds)
  ){
    debounce_time_touch_pin = millis();

    //Change the current selection color by incrementing the value
    if(++current_selection >= current_selection_count){
      current_selection = 0;
    }   
  }

  //Read in the microphone value
  uint16_t mic_value = analogRead(MIC_PIN);

  if(DEBUG == 1){
    Serial.println(mic_value);
    delay(1);
  }
  
  //Check if the microphone value is under the ambient threshold, set mic value to 0 to ignore if it is under the threshold
  if(mic_value < AMBIENT_THRESHOLD){
    mic_value = 0;
  }
  //Check if the microphone value is over the max loudness threshold
  //If it is, set the microphone value to that threshold, this sets the max value for the microphone value
  if(mic_value > MAX_THRESHOLD){
    mic_value = MAX_THRESHOLD;
  }

  //Determine the brightness of the leds by using the map function
  uint8_t brightness = map(mic_value, 0, MAX_THRESHOLD, 0, 255);

  //Set, but not show, the color and brightness of all the LEDs in the LED Matrix
  for (uint16_t j = 0; j < NUMPIXELS; ++j) {
    matrix.setPixelColor(j, matrix.Color(color_matrix[current_selection][0] * brightness, color_matrix[current_selection][1] * brightness, color_matrix[current_selection][2] * brightness));
  }

  //Actually execute and show the set values on the LEDs
  matrix.show();
  
  delay(1);
}

3. Select the board, processor and port:

• Go to Tools > Board and select Microduino/mCookie-Core (328p)
• Go to Tools > Processor and select Atmega328P16M,5V
• Go to Tools > Port and select the available port

4. Upload the program by clicking on the right arrow icon on the top left of the window. Or under Sketch > Upload.

NOTE: If not using the default Core module included in the kits, please follow the selecting the board and processor guide.

Debugging

• Change the DEBUG value from 0 to 1 to enable serial debugging. Re-upload the sketch with that modification.
• Open the Serial monitor. It should start printing the raw Microphone values. These values can be used to tweak the sketch to better suit your environment.
• Note: Change DEBUG back to 0 and re-upload the sketch when debugging is done. With debug mode on there is an added delay when reading Microphone values. Therefore, the light transitions may not seem as smooth when debugging is on.

Tweaking

Variables can be edited to change the threshold / detection value for various functions to better fine tune to your environment.

DEBUG will enable or disable debugging.

LEDMATRIX_PIN defines the pin that connects the LED Matrix

NUMPIXELS defines the number of pixels on the LED Matrix

MIC_PIN defines the pin that connects to the Microphone

TOUCH_PIN defines the pin that connects the Touch Button

AMBIENT_THRESHOLD will change the value that is registered as ambient noise when reading from the Microphone. A lower value is less ambient noise, higher value is louder ambient noise. Values can be retrieved during debugging mode.

• Adjustable between 0 ~ 1023
• Default value is 40

MAX_THRESHOLD will change maximum value the Microphone can register. This is useful to narrow the noise level range and produce a better brightness range. Values can be retrieved during debugging mode.

• Default value is 800
• Adjustable between 0 ~ 1023

DEBOUNCE_TIME_MILLISECONDS will set the time to hold down the touch button to register as a "press"

Usage

Talk or play music towards the Microphone and the LED Matrix should react to the noise loudness. Change the color of the LED Matrix by pressing the Touch Button. There 7 select-able colors. There is a 200 millisecond (1/5 second) delay between Touch Button detection.